Hive数据类型

基本数据类型

对于Hive的String类型相当于数据库的varchar类型，该类型是一个可变的字符串，不过它不能声明其中最多能存储多少个字符，理论上它可以存储2GB的字符数。

集合数据类型

Hive有三种复杂数据类型ARRAY、MAP 和 STRUCT。ARRAY和MAP与Java中的Array和Map类似，而STRUCT与C语言中的Struct类似，它封装了一个命名字段集合，复杂数据类型允许任意层次的嵌套。

• 案例实操

  1. 假设某表有如下一行，我们用JSON格式来表示其数据结构。在Hive下访问的格式为

     { "name": "songsong", "friends": ["bingbing" , "lili"] , //列表Array, "children": { //键值Map, "xiao song": 18 , "xiaoxiao song": 19 } "address": { //结构Struct, "street": "hui long guan" , "city": "beijing" } }

  2. 基于上述数据结构，我们在Hive里创建对应的表，并导入数据。 创建本地测试文件test.txt

     songsong,bingbing_lili,xiao song:18_xiaoxiao song:19,hui long guan_beijing yangyang,caicai_susu,xiao yang:18_xiaoxiao yang:19,chao yang_beijing

     注意：MAP，STRUCT和ARRAY里的元素间关系都可以用同一个字符表示，这里用“_”。

  3. Hive上创建测试表test

     create table test( name string, friends array<string>, children map<string, int>, address struct<street:string, city:string> ) row format delimited fields terminated by ',' collection items terminated by '_' map keys terminated by ':' lines terminated by '\n'; #默认"\n"

     字段解释：

     row format delimited fields terminated by ',' – 列分隔符

     collection items terminated by '_' – MAP STRUCT 和 ARRAY 的分隔符(数据分割符号)

     map keys terminated by ':' – MAP中的key与value的分隔符

     lines terminated by '\n'; – 行分隔符

  4. 导入文本数据到测试表

     hive (default)> load data local inpath ‘/opt/module/datas/test.txt’into table test

  5. 访问三种集合列里的数据，以下分别是ARRAY，MAP，STRUCT的访问方式

     hive (default)> select friends[1],children['xiao song'],address.city from test where name="songsong"; OK _c0 _c1 city lili 18 beijing Time taken: 0.076 seconds, Fetched: 1 row(s)

DDL数据定义

创建数据库

CREATE DATABASE [IF NOT EXISTS] database_name
[COMMENT database_comment]
[LOCATION hdfs_path]
[WITH DBPROPERTIES (property_name=property_value, ...)];

• 创建一个数据库，数据库在HDFS上的默认存储路径是/user/hive/warehouse/*.db。

hive (default)> create database db_hive;

• 避免要创建的数据库已经存在错误，增加if not exists判断。（标准写法）

hive (default)> create database db_hive;
FAILED: Execution Error, return code 1 from org.apache.hadoop.hive.ql.exec.DDLTask. Database db_hive already exists
hive (default)> create database if not exists db_hive;

• 创建一个数据库，指定数据库在HDFS上存放的位置

hive (default)> create database db_hive2 location '/db_hive2.db';

查询数据库

显示数据库

1. 显示数据库

   hive> show databases;

2. 过滤显示查询的数据库

   hive> show databases like 'db_hive*'; OK db_hive db_hive_1

查看数据库详情

1. 显示数据库信息

   hive> desc database db_hive; OK db_hive hdfs://aliyun:9000/user/hive/warehouse/db_hive.db hadoopUSER

2. 显示数据库详细信息，extended

   hive> desc database extended db_hive; OK db_hive hdfs://aliyun:9000/user/hive/warehouse/db_hive.db hadoopUSER

切换当前数据库

hive (default)> use db_hive;

修改数据库

用户可以使用ALTER DATABASE命令为某个数据库的DBPROPERTIES设置键-值对属性值，来描述这个数据库的属性信息。数据库的其他元数据信息都是不可更改的，包括数据库名和数据库所在的目录位置。

hive (default)> alter database db_hive set dbproperties('createtime'='20170830');

在hive中查看修改结果

hive> desc database extended db_hive;
db_name comment location        owner_name      owner_type      parameters
db_hive         hdfs://aliyun:8020/user/hive/warehouse/db_hive.db    hadoop USER    {createtime=20170830}

删除数据库

• 删除空数据库

  hive>drop database db_hive2;

• 如果删除的数据库不存在，最好采用 if exists判断数据库是否存在

  hive> drop database db_hive; FAILED: SemanticException [Error 10072]: Database does not exist: db_hive hive> drop database if exists db_hive2;

• 如果数据库不为空，可以采用cascade命令，强制删除

  hive> drop database db_hive; FAILED: Execution Error, return code 1 from org.apache.hadoop.hive.ql.exec.DDLTask. InvalidOperationException(message:Database db_hive is not empty. One or more tables exist.) hive> drop database db_hive cascade;

创建表

• 建表语法

  CREATE [EXTERNAL] TABLE [IF NOT EXISTS] table_name [(col_name data_type [COMMENT col_comment], ...)] [COMMENT table_comment] [PARTITIONED BY (col_name data_type [COMMENT col_comment], ...)] [CLUSTERED BY (col_name, col_name, ...) [SORTED BY (col_name [ASC|DESC], ...)] INTO num_buckets BUCKETS] [ROW FORMAT row_format] [STORED AS file_format] [LOCATION hdfs_path] [TBLPROPERTIES (property_name=property_value, ...)] [AS select_statement]

• 字段解释说明

  1. CREATE TABLE 创建一个指定名字的表。如果相同名字的表已经存在，则抛出异常；用户可以用 IF NOT EXISTS 选项来忽略这个异常。

  2. EXTERNAL关键字可以让用户创建一个外部表，在建表的同时可以指定一个指向实际数据的路径（LOCATION），在删除表的时候，内部表的元数据和数据会被一起删除，而外部表只删除元数据，不删除数据。

  3. COMMENT为表和列添加注释。

  4. PARTITIONED BY创建分区表

  5. CLUSTERED BY创建分桶表

  6. SORTED BY不常用，对桶中的一个或多个列另外排序

  7. ROW FORMAT

     DELIMITED [FIELDS TERMINATED BY char]

     [COLLECTION ITEMS TERMINATED BY char]

     [MAP KEYS TERMINATED BY char]

     [LINES TERMINATED BY char]

     SERDE serde_name [WITH SERDEPROPERTIES (property_name=property_value, property_name=property_value, ...)]

     用户在建表的时候可以自定义SerDe或者使用自带的SerDe。如果没有指定ROW FORMAT 或者ROW FORMAT DELIMITED，将会使用自带的SerDe。在建表的时候，用户还需要为表指定列，用户在指定表的列的同时也会指定自定义的SerDe，Hive通过SerDe确定表的具体的列的数据。

     SerDe是Serialize/Deserilize的简称， hive使用Serde进行行对象的序列与反序列化。

  8. STORED AS指定存储文件类型

     常用的存储文件类型：SEQUENCEFILE（二进制序列文件）、TEXTFILE（文本）、RCFILE（列式存储格式文件）

     如果文件数据是纯文本，可以使用STORED AS TEXTFILE。如果数据需要压缩，使用 STORED AS SEQUENCEFILE。

  9. LOCATION ：指定表在HDFS上的存储位置。

  10. AS：后跟查询语句，根据查询结果创建表。

  11. LIKE允许用户复制现有的表结构，但是不复制数据。

管理表

• 理论

  默认创建的表都是所谓的管理表，有时也被称为内部表。因为这种表，Hive会（或多或少地）控制着数据的生命周期。Hive默认情况下会将这些表的数据存储在由配置项hive.metastore.warehouse.dir(例如，/user/hive/warehouse)所定义的目录的子目录下。 当我们删除一个管理表时，Hive也会删除这个表中数据。管理表不适合和其他工具共享数据。

• 案例实操

  1. 普通创建表

     create table if not exists student2( id int, name string ) row format delimited fields terminated by '\t' stored as textfile location '/user/hive/warehouse/student2';

  2. 根据查询结果创建表（查询的结果会添加到新创建的表中）

     create table if not exists student3 as select id, name from student;

  3. 根据已经存在的表结构创建表

     create table if not exists student4 like student;

  4. 查询表的类型

     hive (default)> desc formatted student2; Table Type: MANAGED_TABLE

外部表

• 理论

  因为表是外部表，所以Hive并非认为其完全拥有这份数据。删除该表并不会删除掉这份数据，不过描述表的元数据信息会被删除掉。

• 管理表和外部表的使用场景

  每天将收集到的网站日志定期流入HDFS文本文件。在外部表（原始日志表）的基础上做大量的统计分析，用到的中间表、结果表使用内部表存储，数据通过SELECT+INSERT进入内部表。

• 案例实操

  分别创建部门和员工外部表，并向表中导入数据。

  1. 上传数据到HDFS

     hive (default)> dfs -mkdir /student; hive (default)> dfs -put /opt/module/datas/student.txt /student;

  2. 建表语句

     hive (default)> create external table stu ( id int, name string) row format delimited fields terminated by '\t' location '/student';

  3. 查看创建的表

     hive (default)> select * from stu_external; OK stu_external.id stu_external.name 1001 lisi 1002 wangwu

  4. 查看表格式化数据

     hive (default)> desc formatted dept; Table Type: EXTERNAL_TABLE

  5. 删除外部表

     hive (default)> drop table stu_external;

     外部表删除后，hdfs中的数据还在，但是metadata中stu_external的元数据已被删除

管理表与外部表的互相转换

1. 查询表的类型

   hive (default)> desc formatted student2; Table Type: MANAGED_TABLE

2. 修改内部表student2为外部表

   alter table student2 set tblproperties('EXTERNAL'='TRUE');

3. 查询表的类型

   hive (default)> desc formatted student2; Table Type: EXTERNAL_TABLE

4. 修改外部表student2为内部表

   alter table student2 set tblproperties('EXTERNAL'='FALSE');

5. 查询表的类型

   hive (default)> desc formatted student2; Table Type: MANAGED_TABLE

   注意：(‘EXTERNAL’=’TRUE’)和(‘EXTERNAL’=’FALSE’)为固定写法，区分大小写！

分区表

分区表实际上就是对应一个HDFS文件系统上的独立的文件夹，该文件夹下是该分区所有的数据文件。Hive中的分区就是分目录，把一个大的数据集根据业务需要分割成小的数据集。在查询时通过WHERE子句中的表达式选择查询所需要的指定的分区，这样的查询效率会提高很多。

分区表基本操作

1. 引入分区表（需要根据日期对日志进行管理）

   /user/hive/warehouse/log_partition/20170702/20170702.log /user/hive/warehouse/log_partition/20170703/20170703.log /user/hive/warehouse/log_partition/20170704/20170704.log

2. 创建分区表语法

   hive (default)> create table dept ( deptno int, dname string, loc string ) partitioned by (month string) row format delimited fields terminated by '\t';

   注意： 分区字段不能是表中已经存在的数据，可以将分区字段看作表的伪列。

3. 加载数据到分区表中

   hive (default)> load data local inpath '/opt/module/datas/dept.txt' into table default.dept partition(month='201709'); hive (default)> load data local inpath '/opt/module/datas/dept.txt' into table default.dept partition(month='201708'); hive (default)> load data local inpath '/opt/module/datas/dept.txt' into table default.dept partition(month='201707’);

   注意： 分区表加载数据时，必须指定分区

4. 查询分区表中数据

   1. 单分区查询

      hive (default)> select * from dept_partition where month='201709';

   2. 多分区联合查询

      hive (default)> select * from dept_partition where month='201709' union all select * from dept_partition where month='201708' union all select * from dept_partition where month='201707'; _u3.deptno _u3.dname _u3.loc _u3.month 10 ACCOUNTING NEW YORK 201707 10 ACCOUNTING NEW YORK 201708 10 ACCOUNTING NEW YORK 201709 20 RESEARCH DALLAS 201707 20 RESEARCH DALLAS 201708 20 RESEARCH DALLAS 201709 30 SALES CHICAGO 201707 30 SALES CHICAGO 201708 30 SALES CHICAGO 201709 40 OPERATIONS BOSTON 201707 40 OPERATIONS BOSTON 201708 40 OPERATIONS BOSTON 201709

5. 增加分区

   1. 创建单个分区

      hive (default)> alter table dept_partition add partition(month='201706') ;

   2. 同时创建多个分区

      hive (default)> alter table dept_partition add partition(month='201705') partition(month='201704');

6. 删除分区

   1. 删除单个分区

      hive (default)> alter table dept_partition drop partition (month='201704');

   2. 同时删除多个分区

      hive (default)> alter table dept_partition drop partition (month='201705'), partition (month='201706');

7. 查看分区表有多少分区

   hive> show partitions dept_partition;

8. 查看分区表结构

   hive> desc formatted dept_partition; # Partition Information # col_name data_type comment month string

分区表注意事项

• 创建二级分区表

  hive (default)> create table dept_partition2( deptno int, dname string, loc string ) partitioned by (month string, day string) row format delimited fields terminated by '\t';

• 正常的加载数据

  1. 加载数据到二级分区表中

     hive (default)> load data local inpath '/opt/module/datas/dept.txt' into table default.dept_partition2 partition(month='201709', day='13');

  2. 查询分区数据

     hive (default)> select * from dept_partition2 where month='201709' and day='13';

• 把数据直接上传到分区目录上，让分区表和数据产生关联的三种方式

  1. 方式一：上传数据后修复(禁用)

     上传数据

     hive (default)> dfs -mkdir -p /user/hive/warehouse/dept_partition2/month=201709/day=12; hive (default)> dfs -put /opt/module/datas/dept.txt /user/hive/warehouse/dept_partition2/month=201709/day=12;

     查询数据（查询不到刚上传的数据）

     hive (default)> select * from dept_partition2 where month='201709' and day='12';

     执行修复命令

     hive> msck repair table dept_partition2;

     再次查询数据

     hive (default)> select * from dept_partition2 where month='201709' and day='12';

  2. 方式二：上传数据后添加分区(推介)

     上传数据

     hive (default)> dfs -mkdir -p /user/hive/warehouse/dept_partition2/month=201709/day=11; hive (default)> dfs -put /opt/module/datas/dept.txt /user/hive/warehouse/dept_partition2/month=201709/day=11;

     执行添加分区

     hive (default)> alter table dept_partition2 add partition(month='201709', day='11');

     查询数据

     hive (default)> select * from dept_partition2 where month='201709' and day='11';

  3. 方式三：创建文件夹后load数据到分区

     创建目录

     hive (default)> dfs -mkdir -p /user/hive/warehouse/dept_partition2/month=201709/day=10;

     上传数据

     hive (default)> load data local inpath '/opt/module/datas/dept.txt' into table dept_partition2 partition(month='201709',day='10');

     查询数据

     hive (default)> select * from dept_partition2 where month='201709' and day='10';

修改表

重命名表

1. 语法

   ALTER TABLE table_name RENAME TO new_table_name

2. 实操案例

   hive (default)> alter table dept_partition2 rename to dept_partition3;

增加、修改和删除表分区

详见分区表基本操作。

增加/修改/替换列信息

• 语法

  1. 更新列

     ALTER TABLE table_name CHANGE [COLUMN] col_old_name col_new_name column_type [COMMENT col_comment] [FIRST|AFTER column_name]

  2. 增加和替换列

     ALTER TABLE table_name ADD|REPLACE COLUMNS (col_name data_type [COMMENT col_comment], ...)

  注： ADD是代表新增一字段，字段位置在所有列后面(partition列前)，REPLACE则是表示替换表中所有字段。

• 实操案例

  1. 查询表结构

     hive> desc dept_partition;

  2. 添加列

     hive (default)> alter table dept_partition add columns(deptdesc string);

  3. 查询表结构

     hive> desc dept_partition;

  4. 更新列

     hive (default)> alter table dept_partition change column deptdesc desc int;

  5. 查询表结构

     hive> desc dept_partition;

  6. 替换列

     hive (default)> alter table dept_partition replace columns(deptno string, dname string, loc string);

  7. 查询表结构

     hive> desc dept_partition;

删除表

hive (default)> drop table dept_partition;

DML数据操作

数据导入

向表中装载数据（Load）

• 语法

  hive> load data [local] inpath '/opt/module/datas/student.txt' [overwrite] into table student [partition (partcol1=val1,…)];

  load data: 表示加载数据

  local: 表示从本地加载数据到hive表；否则从HDFS加载数据到hive表

  inpath: 表示加载数据的路径

  overwrite: 表示覆盖表中已有数据，否则表示追加

  into table: 表示加载到哪张表

  student: 表示具体的表

  partition: 表示上传到指定分区

• 实操案例

  1. 创建一张表

     hive (default)> create table student(id string, name string) row format delimited fields terminated by '\t';

  2. 加载本地文件到hive

     hive (default)> load data local inpath '/opt/module/datas/student.txt' into table default.student;

  3. 加载HDFS文件到hive中

     上传文件到HDFS

     hive (default)> dfs -put /opt/module/datas/student.txt /user/hadoop/hive;

     加载HDFS上数据

     hive (default)> load data inpath '/user/hadoop/hive/student.txt' into table default.student;

  4. 加载数据覆盖表中已有的数据

     上传文件到HDFS

     hive (default)> dfs -put /opt/module/datas/student.txt /user/hadoop/hive;

     加载数据覆盖表中已有的数据

     hive (default)> load data inpath '/user/hadoop/hive/student.txt' overwrite into table default.student;

通过查询语句向表中插入数据（Insert）

1. 创建一张分区表

   hive (default)> create table student(id int, name string) partitioned by (month string) row format delimited fields terminated by '\t';

2. 基本插入数据

   hive (default)> insert into table student partition(month='201709') values(1,'wangwu'),(2,’zhaoliu’);

3. 基本模式插入（根据单张表查询结果）

   hive (default)> insert overwrite table student partition(month='201708') select id, name from student where month='201709';

   insert into： 以追加数据的方式插入到表或分区，原有数据不会删除

   insert overwrite： 会覆盖表或分区中已存在的数据

   注意： insert不支持插入部分字段

4. 多表（多分区）插入模式（根据多张表查询结果）

   hive (default)> from student insert overwrite table student partition(month='201707') select id, name where month='201709' insert overwrite table student partition(month='201706') select id, name where month='201709';

查询语句中创建表并加载数据（CTAS）

详见创建表。

根据查询结果创建表（查询的结果会添加到新创建的表中）

create table if not exists student3 as select id, name from student;

创建表时通过Location指定加载数据路径

1. 上传数据到hdfs上

   hive (default)> dfs -mkdir /student; hive (default)> dfs -put /opt/module/datas/student.txt /student;

2. 创建表，并指定在hdfs上的位置

   hive (default)> create external table if not exists student5( id int, name string ) row format delimited fields terminated by '\t' location '/student;

3. 查询数据

   hive (default)> select * from student5;

Import数据到指定Hive表中

注意：先用export导出后，再将数据导入。

hive (default)> import table student2 partition(month='201709') from
 '/user/hive/warehouse/export/student';

数据导出

Insert导出

1. 将查询的结果导出到本地

   hive (default)> insert overwrite local directory '/opt/module/datas/export/student' select * from student;

2. 将查询的结果格式化导出到本地

   hive(default)>insert overwrite local directory '/opt/module/datas/export/student1' ROW FORMAT DELIMITED FIELDS TERMINATED BY '\t' select * from student;

3. 将查询的结果导出到HDFS上(没有local)

   hive (default)> insert overwrite directory '/user/hadoop/student2' ROW FORMAT DELIMITED FIELDS TERMINATED BY '\t' select * from student;

Hadoop命令导出到本地

hive (default)> dfs -get /user/hive/warehouse/student/month=201709/000000_0
/opt/module/datas/export/student3.txt;

Hive Shell 命令导出

基本语法：（hive -f/-e 执行语句或者脚本 > file）

[hadoop@hadoop102 hive]$ bin/hive -e 'select * from default.student;' >
 /opt/module/datas/export/student4.txt;

Export导出到HDFS上

(defahiveult)> export table default.student to '/user/hive/warehouse/export/student';

export和import主要用于两个Hadoop平台集群之间Hive表迁移。

Sqoop导出

后续的博客讲解

清除表中数据（Truncate）

注意：Truncate只能删除管理表，不能删除外部表中数据

hive (default)> truncate table student;